10 REM KONVERTering av tecken
15 REM Program av Gunnar Tidner
20 REM Tecknena i X$ utbytes mot
30 REM motsvarande tecken i Y$
40 DIM X$=127,Y$=127,C$(127)=10,A$=120,B$=120
50 X$="ABCDE"
60 Y$="abcde"
70 IF LEN(X$)<>LEN(Y$) THEN ; CHR$(7)"Olika antal tecken i X och Y!"
80 REM ****** Initiering ******
90 FOR I%=1 TO 127%
100 C$(I%)=CHR$(I%)
110 NEXT I%
120 FOR I%=1% TO LEN(X$)
130 C$(ASC(RIGHT$(X$,I%)))=MID$(Y$,I%,1%)
140 NEXT I%
150 C$(93%)="AA"
160 C$(94%)="" : REM exempel 1 tecken utbyts mot teckenstr{ng
170 ; TAB(5)"Konverteringstabell:" : ;
180 ; TAB(7)"fr}n";TAB(19)"till" : ;
190 FOR I%=1 TO 127%
200 IF ASC(C$(I%))<>I% THEN ; TAB(8)CHR$(I%)TAB(20)C$(I%)
210 NEXT I%
220 REM *** Start konvertering ***
230 ; "Infil:"; : INPUT F1$
240 OPEN F1$ ASFILE 1
250 ; "Utfil:"; : INPUT F2$
260 PREPARE F2$ ASFILE 2
270 ONERRORGOTO 330
280 FOR K%=1 TO 5000
290 INPUTLINE #1,A$ : A$=LEFT$(A$,LEN(A$)-2%)
300 GOSUB 350
310 ; #2,B$
320 NEXT K%
330 CLOSE 2 : ; F1$;" har konverterats till ";F2$
340 END
350 REM Subrutin f|r teckenkonvertering
360 REM av A$ till B$
370 B$=""
380 FOR I%=1% TO LEN(A$)
390 B$=B$+C$(ASC(RIGHT$(A$,I%)))
400 NEXT I%
410 RETURN