1 REM Ins{nd av Lennart Einarsson <6554> 1986-06-01 14.12.06
10 REM ..... TV-DX
20 REM .....
30 REM ..... ABC80
40 REM ...... 40tkn
50 GOSUB 1290
60 GOSUB 1180
70 RANDOMIZE
80 DEFFNC=.3/C1%+1.02/C2%
90 DEFFNR=RND+RND+RND+RND+RND+RND+FNC
100 C1%=7% : C2%=42%
110 P%=0% : ; CUR(17%,34%)" 0FF"
120 ; CUR(17%,34%); : GET K$
130 IF K$="P" THEN 150
140 IF K$="E" THEN 530 ELSE 110
150 ; CUR(17%,34%)" ON"
160 POKE 65008%,255%,255%,255%
170 ; CUR(23%,29)SPACE$(9%); : GOTO 340
180 FOR I%=2% TO 18%
190 ; CUR(I%,3%)STRING$(22%,32%+9%*RND)
200 NEXT I% : OUT 6%,11%
210 IF INP(56%) AND 128% THEN 250
220 IF PEEK(65009%)<207% THEN 480
230 IF FNR>3.8 THEN GOSUB 540
240 GOTO 180
250 G%=INP(56%)-128%
260 IF G%=85% THEN 310
270 IF G%=86% THEN 340
280 IF G%=72% THEN 370
290 IF G%=76% THEN 430
300 GOTO 180
310 POKE 32162%,213%,200%,198%
320 POKE 31946%,86%,72%,70%
330 H%=1% : GOTO 180
340 POKE 32162%,85%,72%,70%
350 POKE 31946%,214%,200%,198%
360 H%=0% : GOTO 180
370 IF H% THEN 410
380 C1%=C1%+1% : IF C1%>12% THEN C1%=12%
390 ; CUR(12%,33%)" "
400 ; CUR(12%,33%)C1% : GOTO 180
410 C2%=C2%+1% : IF C2%>68% THEN C2%=68%
420 ; CUR(6%,33%)C2% : GOTO 180
430 IF H% THEN 460
440 C1%=C1%-1% : IF C1%<2% THEN C1%=2%
450 GOTO 390
460 C2%=C2%-1% : IF C2%<21% THEN C2%=21%
470 GOTO 420
480 FOR I%=2% TO 18%
490 ; CUR(I%,3%)STRING$(22%,32%)
500 NEXT I% : OUT 6%,0%
510 ; CUR(23%,29%)"QSO:"P%;
520 GOTO 110
530 ; CHR$(12%,7%)"GOOD NIGHT." : END
540 RESTORE 840 : FOR I%=2% TO 18%
550 READ F$
560 IF X% THEN X%=0% : GOTO 590 ELSE X%=1%
570 ; CUR(I%,3%)STRING$(22%,32%+9%*RND)
580 GOTO 600
590 ; CUR(I%,3%)F$
600 NEXT I% : OUT 6%,203%
610 IF INP(56%) AND 128% THEN 250
620 IF PEEK(65009%)<207% THEN 480
630 IF RND<.28 THEN RETURN
640 R=FNR
650 IF R>=3.8 THEN 660 ELSE 540
660 RESTORE 840 : FOR I%=2% TO 18%
670 READ F$ : ; CUR(I%,3%)F$
680 NEXT I% : OUT 6%,67%
690 IF H% RESTORE 1110 ELSE RESTORE 1020
700 IF R>=3.8 THEN I%=1%
710 IF R>=3.9 THEN I%=2%
720 IF R>=4% THEN I%=3%
730 IF R>=4.2 THEN I%=4%
740 IF R>=4.4 THEN I%=5%
750 IF R>=4.6 THEN I%=6%
760 IF R>=4.8 THEN I%=7%
770 IF R>=5% THEN I%=8%
780 IF R>=5.4 THEN I%=9%
790 FOR X%=1% TO I% : READ A$,B$,G%
800 NEXT X% : ; CUR(5%,10%)CHR$(135%)A$CHR$(151%)CUR(16%,10%)CHR$(135%)B$CHR$(151%)
810 P%=P%+G%
820 FOR T=1% TO 3491% : OUT 6%,67%
830 NEXT T : RETURN
840 REM TV-PICTURE
850 DATA " "
860 DATA " 7#############k "
870 DATA " 5 j "
880 DATA " 7#k5 j##k "
890 DATA " 7#k j##k "
900 DATA " 7#k 5555555555555j##k "
910 DATA " 7#k j##k "
920 DATA " 7#k j##k "
930 DATA " 7#k j##k "
940 DATA " 7#k j##k "
950 DATA " 7#k j##k "
960 DATA " 7#k j##k "
970 DATA " 7#k 5555555555555j##k "
980 DATA " 7#k j##k "
990 DATA " ##k5 j### "
1000 DATA " 5 j "
1010 DATA " upppppppppppppz "
1020 DATA " TV 1 ","SVERIGE",1
1030 DATA "AALBORG","DANMARK",5
1040 DATA " NRK "," NORGE ",9
1050 DATA "","YLE.HLK",11
1060 DATA " MOCKBA"," CCCP ",13
1070 DATA " SRG 1 "," Z^RICH",15
1080 DATA " RTE 1 "," EIRE ",17
1090 DATA " RVU "," ISLAND",27
1100 DATA " WOR-TV"," N.Y. ",97
1110 DATA " TV 2 ","SVERIGE",1," TV 2 ","SVERIGE",2," TV 2 ","SVERIGE",3
1120 DATA " ZDF ","",19
1130 DATA ""," PRAHA ",20
1140 DATA ""," CCCP ",21
1150 DATA " RTB 2 "," HAAG ",23
1160 DATA " BBC 1 "," LONDON",29
1170 DATA " RTE 2 "," EIRE ",35
1180 ; CHR$(12%)
1190 ; CUR(0%,1%)"7#########################k"CUR(1%,1%)"57#######################kj"
1200 ; CUR(21%,1%)"upppppppppppppppppppppppppz"CUR(20%,1%)"5upppppppppppppppppppppppzj"
1210 FOR I%=2% TO 19%
1220 ; CUR(I%,1%)"55"CUR(I%,26%)"jj"
1230 NEXT I% : FOR I%=0% TO 21%
1240 ; CUR(I%,0%)CHR$(151%)
1250 ; CUR(I%,28%)CHR$(135%) : NEXT I%
1260 ; CUR(3%,34%)"UHF"CUR(4%,32%)"CHANNEL"CUR(6%,34%)"42"
1270 ; CUR(9%,34%)"VHF"CUR(10%,32%)"CHANNEL"CUR(12%,34%)"7"
1280 ; CUR(15%,33%)"POWER"CUR(23%,7%)"*** LUMA TV ***"; : RETURN
1290 IF PEEK(590%)<>40% ; INP(3%)
1300 ; CHR$(12%)TAB(16%)"TV-DX" : ; STRING$(38%,45%)
1310 ; : ; : ; "HEJ D[R!" : ; "MITT I H\GSOMMAREN UPPKOMMER DE B[STA" : ; "TILLF[LLEN ATT KUNNA SE UTRIKES TV."
1320 ; "M]NGA SER BARA ATT TV1-S[NDAREN [R" : ; "ST\RD OCH BLIR IRRITERADE, MEN TV-DX-"
1330 ; "AREN BLIR LYCKLIG!"
1340 ; "DETTA PROGRAM SIMULERAR EN SOMMARDAG" : ; "FRAMF\R DIN TV-MOTTAGARE. ABC80:S"
1350 ; "MONITOR GER DIG ILLUSION OM HUR ENORMT" : ; "ROLIGT DET [R ATT TV-DX:A!"
1360 ; : ; "KOMMANDON:"
1370 ; "P=POWER ON U=UHF V=VHF"
1380 ; "H=H\GRE KANAL L=L[GRE KANAL E=END"
1390 ; : ; "PROGRAMMET G]R FYRA MINUTER, SEDAN AV-" : ; "BRYTS DET OCH VISAR DIN QSO-PO[NG."
1400 ; "SVERIGES ALLA S[NDARE LIGGER NERE F\R" : ; "REPARATION MED N]GRA F] UNDANTAG."
1410 GET K$ : RETURN