1 REM Ins{nt av 2839
100 REM ! -----------------------------
110 REM ! --- Ett program fr}n CDS. ---
120 REM ! --- ===================== ---
130 REM ! --- ---
140 REM ! --- Program DELETE__.BAS ---
150 REM ! --- Version 1.3 ---
160 REM ! --- Created 1983-10-10 ---
170 REM ! --- Copyright CDS ---
180 REM ! --- Lars-B|rje Cid ---
190 REM ! --- Utrustning DISK ---
200 REM ! --- ---
210 REM ! -----------------------------
220 REM !
230 REM
240 DIM F$(119%)=12%,F1$(119%)=12%
250 ; CHR$(12%);
260 ; " ** ABC80 - FILE-DELETE **"
270 ; STRING$(PEEK(734%),61%)
280 REM
290 REM --
300 REM
310 ; CUR(4%,0%)"Ange drive (<0>/1): "; : INPUTLINE A$
320 IF LEN(A$)=2% A%=0% : ; A% : ; : GOTO 350
330 ONERRORGOTO 770 : A%=VAL(LEFT$(A$,LEN(A$)-2%)) : ; : ;
340 IF NOT (A%=1% OR A%=0%) 770
350 POKE -767%,A% : Z%=CALL(24678%,0%)
360 IF PEEK(-747%) 710
370 D$='DR'+NUM$(PEEK(-767%))+':'
380 REM
390 REM --
400 REM
410 FOR S%=8% TO 15% : Z%=CALL(24678%,S%*32%) : IF PEEK(-747%) 710
420 FOR K%=-2800% TO -2576% STEP 16
430 X$='' : FOR J%=4% TO 14%
440 X$=X$+CHR$(PEEK(K%+J%))
450 IF PEEK(K%+J%)<32% OR PEEK(K%+J%)>127% 490
460 IF J%=11% X$=X$+'.'
470 NEXT J% : F%=F%+1%
480 F$(F%)=X$
490 NEXT K% : NEXT S% : ;
500 REM
510 REM --
520 REM
530 ; : ; 'Tillg{nliga kommandon: '
540 ; : ; 'A - Ta ej bort resten av skivan.'
550 ; 'I - Ta bort resten av skivan.'
560 ; 'J - Ta bort denna fil.'
570 ; 'N el RETURN - Ta ej bort denna fil. '
580 ; : ; 'Fas 1' : FOR I%=1% TO F%
590 ; 'Delete 'F$(I%)': '; : INPUTLINE A$ : ;
600 REM
610 REM --
620 REM
630 A$=CHR$(ASC(LEFT$(A$,1%)) AND 223%)
640 IF A$='J' F1%=F1%+1% : F1$(F1%)=F$(I%)
650 IF A$='I' FOR J%=I% TO F% : F1%=F1%+1% : F1$(F1%)=F$(J%) : ; 'Delete 'F$(J%)':' : NEXT J% : GOTO 750
660 IF A$='A' 750
670 NEXT I% : GOTO 750
680 REM
690 REM --
700 REM
710 ; : ; : ; "Fel p} drive"A% : GOTO 770
720 REM
730 REM --
740 REM
750 ; : ; 'Fas 2' : FOR I%=1% TO F1% : ; F1$(I%)' ';
760 KILL D$+F1$(I%) : ; 'Deleted.' : NEXT I%
770 END